#! Praat script p2b/measureEnthropies.praat
# Paul Boersma, June 7, 2001

Read from file... correct.ResultsMFC
To Categories (responses)
enthropy = Get enthropy
categories = 2 ^ enthropy
echo Stimuli Enthropy Categories
printline               'enthropy:2'         'categories:1'
printline Responses Enthropy1 Enthropy2 Categories1 Categories2
call one 1 fm
call one 2 jdg
call one 3 dw
call one 4 ds
call one 5 mvb
call one 6 evd
call one 7 mb
;call one 8 mg
call one 9 is
call one 10 mk
call one 11 ben
select ResultsMFC correct
plus Categories correct
Remove

procedure one number listener$
   Read from file... listeners/'listener$'.Collection
   if numberOfSelected ("ResultsMFC") < 3
      exit Listener "'listener$'" does not have three results.
   endif
   select ResultsMFC correct
   plus ResultsMFC one
   Remove unshared stimuli
   To Categories (responses)
   enthropy1 = Get enthropy
   select ResultsMFC correct
   plus ResultsMFC two
   Remove unshared stimuli
   To Categories (responses)
   enthropy2 = Get enthropy
   select ResultsMFC one
   plus ResultsMFC two
   plus ResultsMFC three
   plus ResultsMFC one_shared
   plus ResultsMFC two_shared
   plus Categories one_shared
   plus Categories two_shared
   Remove
   categories1 = 2 ^ enthropy1
   categories2 = 2 ^ enthropy2
   printline 'number' 'listener$'        'enthropy1:2'       'enthropy2:2'       'categories1:1'       'categories2:1'
endproc