#! Praat script p2b/getProductionData.praat
# Paul Boersma, October 26, 2001

Open long sound file... speakers/cll_est2.wav
Read from file... stimulusNames.Strings
Read from file... speakers/cll_est2.TextGrid
Create TableOfReal... formantTable 125 2
Set column label (index)... 1 ##%F_1
Set column label (index)... 2 ##%F_2
for istim to 125
   select Strings stimulusNames
   stimulusName$ = Get string... istim
   time$ = mid$ (stimulusName$, 7, 3) + "." + mid$ (stimulusName$, 11, 2)
   time = 'time$'
   syllable$ = mid$ (stimulusName$, 14, 100)
   select TextGrid cll_est2
   interval = Get interval at time... 2 time+0.02
   interval$ = Get label of interval... 2 interval
   if interval$= syllable$
      tier = 2
   else
      interval = Get interval at time... 4 time+0.02
      interval$ = Get label of interval... 4 interval
      if interval$ = syllable$
         tier = 4
      else
         interval = Get interval at time... 6 time+0.02
         interval$ = Get label of interval... 6 interval
         if interval$ = syllable$
            tier = 6
         else 
            exit not found
         endif
      endif
   endif  
   startingpoint = Get starting point... tier interval
   endpoint = Get end point... tier interval
   numberpoints = Get number of points... tier+1
   for ipoint to numberpoints 
      time = Get time of point... tier+1 ipoint
      if time > startingpoint and time < endpoint
         measuretime = time
      endif
   endfor
   select LongSound cll_est2
   Extract part... measuretime-0.05 measuretime+0.05  yes
   To Formant (burg)... 0.001 5 5500 0.025 50
   f1 = Get value at time... 1 measuretime Hertz Linear
   f2 = Get value at time... 2 measuretime Hertz Linear
   select Sound cll_est2 
   plus Formant cll_est2
   Remove
   select TableOfReal formantTable
   Set row label (index)... istim 'stimulusName$'
   Set value... istim 1 f1
   Set value... istim 2 f2
   ;pause 'measuretime' "'syllable$'" 'tier' 'f1:0' 'f2:0'
endfor