# 5.02_Sigh.make
#
# Praat script that computes the sound, tube widths, air pressures, and air velocities
# for a sigh, as shown in figures 5.2-3 of
#    Paul Boersma (1998): Functional Phonology, section 5.2.
# http://fonsg3.hum.uva.nl/paul/
#
form Sigh
   boolean Inhale 0
   boolean Raised_velum 1
endform

Create Speaker... speaker Female 2
Create empty Artword... sigh 0.5

! Lungs falling from 132 to 120 mm in the first 30 milliseconds
if 'Inhale'
   Set target... 0.00 -0.1 Lungs
else
   Set target... 0.00 0.1 Lungs
endif
Set target... 0.03 0.0 Lungs
Set target... 10 0.0 Lungs

if 'Inhale'
   # If all laryngeal muscles are relaxed, the glottis will be 5 mm wide (formula 2.38).
   # At inspiration, the glottis actively widened to 8 mm
   # by pulling posterior cricoarytenoid (formula 2.38).
   Set target... 0 1 PosteriorCricoarytenoid
   Set target... 1 1 PosteriorCricoarytenoid
endif

# To get air velocities in the vocal tract high enough for generating turbulence noise,
# raise the velum so that all the air flow is forced through the oral cavity.
if 'Raised_velum'
   Set target... 0 1 LevatorPalatini
   Set target... 1 1 LevatorPalatini
endif

# tube 15: lungs
# tube 27: bronchi
# tube 36: lower glottis
# tube 52: velum
# tube 60: mouth
# tube 78: nostrils

select Speaker speaker
plus Artword sigh
To Sound... 22050 25   15 60 78   15 60 78   15 60 78

select Speaker speaker
plus Artword sigh
To Sound... 22050 25   52 36 27   52 36 27   52 36 27

select Speaker speaker
plus Artword sigh
Remove

select all
if 'Raised_velum'
   if 'Inhale'
      Write to binary file... 5.02_inhale_oral.data
   else
      Write to binary file... 5.02_exhale_oral.data
   endif
else
   if 'Inhale'
      Write to binary file... 5.02_inhale_nasal.data
   else
      Write to binary file... 5.02_exhale_nasal.data
   endif
endif